home *** CD-ROM | disk | FTP | other *** search
/ Workbench Add-On / Workbench Add-On - Volume 1.iso / BBS-Archive / Dev / GNU-SMALLTALK.lha / Collection.st < prev    next >
Text File  |  1992-02-15  |  7KB  |  276 lines
  1. "======================================================================
  2. |
  3. |   Collection Method Definitions
  4. |
  5.  ======================================================================"
  6.  
  7.  
  8. "======================================================================
  9. |
  10. | Copyright (C) 1990, 1991, 1992 Free Software Foundation, Inc.
  11. | Written by Steve Byrne.
  12. |
  13. | This file is part of GNU Smalltalk.
  14. |
  15. | GNU Smalltalk is free software; you can redistribute it and/or modify it
  16. | under the terms of the GNU General Public License as published by the Free
  17. | Software Foundation; either version 1, or (at your option) any later version.
  18. | 
  19. | GNU Smalltalk is distributed in the hope that it will be useful, but WITHOUT
  20. | ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  21. | FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  22. | details.
  23. | 
  24. | You should have received a copy of the GNU General Public License along with
  25. | GNU Smalltalk; see the file COPYING.  If not, write to the Free Software
  26. | Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.  
  27. |
  28.  ======================================================================"
  29.  
  30.  
  31. "
  32. |     Change Log
  33. | ============================================================================
  34. | Author       Date       Change 
  35. | sbb         15 Feb 92      Switched the collection creating enumerators to use
  36. |              the copyEmpty message, so it can be overridden by
  37. |              subclasses (like SortedCollection) when copying empty
  38. |              involves more than just doing a new.
  39. |
  40. | sbb         16 Mar 91      Class creation now separate statement.
  41. |
  42. | sbb          7 Feb 91      Fixed detect: to return the value that detect:ifNone:
  43. |              returns.
  44. |
  45. | sbb         21 Sep 90      Fixed store: to be storeOn:
  46. |
  47. | sbyrne     25 Apr 89      created.
  48. |
  49. "
  50.  
  51. Object subclass: #Collection
  52.        instanceVariableNames: ''
  53.        classVariableNames: ''
  54.        poolDictionaries: ''
  55.        category: nil
  56. !
  57.  
  58. Collection comment: 
  59. 'I am an abstract class.  My instances are collections of objects.  My
  60. subclasses may place some restrictions or add some definitions to how
  61. the objects are stored or organized; I say nothing about this.  I merely
  62. provide some object creation and access routines for general collections
  63. of objects.' !
  64.  
  65.  
  66. !Collection class methodsFor: 'instance creation'!
  67.  
  68. with: anObject
  69.     ^self new add: anObject; yourself
  70. !
  71.  
  72. with: firstObject with: secondObject
  73.     ^self new add: firstObject; add: secondObject; yourself
  74. !
  75.  
  76. with: firstObject with: secondObject with: thirdObject
  77.     ^self new add: firstObject; add: secondObject; add: thirdObject; yourself
  78. !
  79.  
  80. with: firstObject with: secondObject with: thirdObject with: fourthObject
  81.     ^self new add: firstObject; add: secondObject; add: thirdObject;
  82.         add: fourthObject; yourself
  83. ! !
  84.  
  85.  
  86.  
  87. !Collection methodsFor: 'Adding to a collection'!
  88.  
  89. add: newObject
  90.     self subclassResponsibility
  91. !
  92.  
  93. addAll: aCollection
  94.     "Adds all the elements of 'aCollection' to the receiver"
  95.     aCollection do: [ :element | self add: element ].
  96.     ^aCollection
  97. ! !
  98.  
  99.  
  100.  
  101. !Collection methodsFor: 'Removing from a collection'!
  102.  
  103. remove: oldObject ifAbsent: anExceptionBlock
  104.     self subclassResponsibility
  105. !
  106.  
  107. remove: oldObject
  108.     self remove: oldObject
  109.          ifAbsent: [ ^self error: 'Failed to remove object' ].
  110.     ^oldObject
  111. !
  112.  
  113. removeAll: aCollection
  114.     " ??? we're supposed to report an error if an object can't be removed
  115.       properly.  I've elected to let remove: report the error.  Also, it's
  116.       not clear whether we're supposed to remove all occurrences of the
  117.       members of aCollection from the receiver, or only the first."
  118.     aCollection do: [ :element | self remove: element ].
  119.     ^aCollection
  120. !!
  121.  
  122.  
  123.  
  124. !Collection methodsFor: 'testing collections'!
  125.  
  126. includes: anObject
  127.     self do: [ :element | anObject = element ifTrue: [ ^true ] ].
  128.     ^false
  129. !
  130.  
  131. isEmpty
  132.     ^self size == 0
  133. !
  134.  
  135. occurrencesOf: anObject
  136.     | count |
  137.     count _ 0.
  138.     self do: [ :element | anObject == element ifTrue: [ count _ count + 1 ] ].
  139.     ^count
  140. !
  141.  
  142. size
  143.     | count |
  144.     count _ 0.
  145.     self do: [ :element | count _ count + 1].
  146.     ^count
  147. !!
  148.  
  149.  
  150.  
  151. !Collection methodsFor: 'enumerating the elements of a collection'!
  152.  
  153. do: aBlock
  154.     self subclassResponsibility
  155. !
  156.  
  157. select: aBlock
  158.     | newCollection |
  159.     newCollection _ self copyEmpty.
  160.     self do: [ :element | (aBlock value: element)
  161.                             ifTrue: [ newCollection add: element ]
  162.          ].
  163.     ^newCollection
  164. !
  165.  
  166. reject: aBlock
  167.     | newCollection |
  168.     newCollection _ self copyEmpty.
  169.     self do: [ :element | (aBlock value: element)
  170.                             ifFalse: [ newCollection add: element ]
  171.          ].
  172.     ^newCollection
  173. !
  174.  
  175. collect: aBlock
  176.     | newCollection |
  177.     newCollection _ self copyEmpty.
  178.     self do: [ :element | newCollection add: (aBlock value: element) ].
  179.     ^newCollection
  180. !
  181.  
  182. detect: aBlock ifNone: exceptionBlock
  183.     self do: [ :element | (aBlock value: element) ifTrue: [ ^element ] ].
  184.     exceptionBlock value    
  185. !
  186.     
  187. detect: aBlock
  188.     ^self detect: aBlock ifNone: [ self error: 'Collection detect: failed']
  189. !
  190.  
  191. inject: thisValue into: binaryBlock
  192.     self do: [ :element | thisValue _ binaryBlock value: thisValue
  193.                                                   value: element ].
  194.     ^thisValue
  195. !!
  196.  
  197.  
  198.  
  199. !Collection methodsFor: 'converting'!
  200.  
  201. asBag
  202.     | aBag |
  203.     aBag _ Bag new.
  204.     self do: [ :element | aBag add: element ].
  205.     ^aBag
  206. !
  207.  
  208. asSet
  209.     | aSet |
  210.     aSet _ Set new: self size.
  211.     self do: [ :element | aSet add: element ].
  212.     ^aSet
  213. !
  214.  
  215. asOrderedCollection
  216.     | anOrderedCollection |
  217.     anOrderedCollection _ OrderedCollection new: self size.
  218.     self do: [ :element | anOrderedCollection add: element ].
  219.     ^anOrderedCollection
  220. !
  221.  
  222. asSortedCollection
  223.     | aSortedCollection |
  224.     aSortedCollection _ SortedCollection new.
  225.     self do: [ :element | aSortedCollection add: element ].
  226.     ^aSortedCollection
  227. !
  228.  
  229. asSortedCollection: aBlock
  230.     | aSortedCollection |
  231.     aSortedCollection _ SortedCollection sortBlock: aBlock.
  232.     self do: [ :element | aSortedCollection add: element ].
  233.     ^aSortedCollection
  234. ! !
  235.  
  236.  
  237.  
  238. !Collection methodsFor: 'copying'!
  239.  
  240. copyEmpty
  241.     ^self species new
  242. ! !
  243.     
  244.  
  245.  
  246. !Collection methodsFor: 'printing'!
  247.  
  248. printOn: aStream
  249.     aStream nextPutAll: self classNameString.
  250.     aStream nextPutAll: ' ('.
  251.     self do:
  252.         [ :element | element printOn: aStream.
  253.              aStream space ].
  254.     aStream nextPut: $)
  255. !!
  256.  
  257.  
  258.  
  259. !Collection methodsFor: 'storing'!
  260.  
  261. storeOn: aStream
  262.     | noElements |
  263.     aStream nextPut: $(.
  264.     aStream nextPutAll: self classNameString.
  265.     aStream nextPutAll: ' new'.
  266.     noElements _ true.
  267.     self do:
  268.         [ :element | aStream nextPutAll: ' add: '.
  269.                      element storeOn: aStream.
  270.              aStream nextPut: $;.
  271.              noElements _ false ].
  272.     noElements ifFalse: [ aStream nextPutAll: ' yourself' ].
  273.     aStream nextPut: $)
  274. !!
  275.  
  276.